#version 450

#include "dequant_head.glsl"

layout(local_size_x = 256, local_size_y = 1, local_size_z = 1) in;

layout (binding = 0) readonly buffer A {block_q8_0 data_a[];};
layout (binding = 1) writeonly buffer D {D_TYPE data_b[];};

void main() {
    const uint i = gl_WorkGroupID.x * 4 + gl_LocalInvocationID.x / 64;

    const uint tid = gl_LocalInvocationID.x % 64;
    const uint il  = tid/32;
    const uint ir  = tid%32;
    const uint ib = 32*i + ir;
    if (ib >= p.nel / 32) {
        return;
    }

#ifdef DEQUANT_TRANSPOSE
    // read [HS, NH, KV, NS], write [HS, KV, NH, NS]
    const uint HS = p.M, NH = p.K, KVn = p.stride_a;
    const uint e0 = ib * 32;
    const uint b_idx = (e0 % HS)
                     + ((e0 / (HS * NH)) % KVn) * HS
                     + ((e0 / HS) % NH) * (HS * KVn)
                     + (e0 / (HS * NH * KVn)) * (HS * KVn * NH)
                     + 16 * il;
#else
    const uint b_idx = 1024*i + 32*ir + 16*il;
#endif

    const float d = float(data_a[ib].d);

    const uint q_idx = 16*il;

    [[unroll]] for (uint l = 0; l < 16; l += 2) {
        data_b[b_idx + l    ] = D_TYPE(d * data_a[ib].qs[q_idx + l    ]);
        data_b[b_idx + l + 1] = D_TYPE(d * data_a[ib].qs[q_idx + l + 1]);
    }
}