char-fork/llama.cpp

git clone https://git.t4t.associates/char-fork/llama.cpp

Johannes Gäßlerggml: backend-agnostic tensor parallelism (experimental) (#19378)d6f303004

char/aliceai-t5-moe
brancheschar/aliceai-t5-moeall refs →
964 B36 linesraw
1# cmake/FindNCCL.cmake
2
3# NVIDIA does not distribute CMake files with NCCl, therefore use this file to find it instead.
4
5find_path(NCCL_INCLUDE_DIR
6    NAMES nccl.h
7    HINTS ${NCCL_ROOT} $ENV{NCCL_ROOT} $ENV{CUDA_HOME} /usr/local/cuda
8    PATH_SUFFIXES include
9)
10
11find_library(NCCL_LIBRARY
12    NAMES nccl
13    HINTS ${NCCL_ROOT} $ENV{NCCL_ROOT} $ENV{CUDA_HOME} /usr/local/cuda
14    PATH_SUFFIXES lib lib64
15)
16
17include(FindPackageHandleStandardArgs)
18find_package_handle_standard_args(NCCL
19    DEFAULT_MSG
20    NCCL_LIBRARY NCCL_INCLUDE_DIR
21)
22
23if(NCCL_FOUND)
24    set(NCCL_LIBRARIES ${NCCL_LIBRARY})
25    set(NCCL_INCLUDE_DIRS ${NCCL_INCLUDE_DIR})
26
27    if(NOT TARGET NCCL::NCCL)
28        add_library(NCCL::NCCL UNKNOWN IMPORTED)
29        set_target_properties(NCCL::NCCL PROPERTIES
30            IMPORTED_LOCATION "${NCCL_LIBRARY}"
31            INTERFACE_INCLUDE_DIRECTORIES "${NCCL_INCLUDE_DIR}"
32        )
33    endif()
34endif()
35
36mark_as_advanced(NCCL_INCLUDE_DIR NCCL_LIBRARY)